Disconnect() Stops Nano 33 BLE from Advertising?

[ebarnette-ms]

Whenever I call disconnect() the radio doesn't show up in an LE scan.

When I run this function:

void resetAdvertising(){
  // stop advertising
  BLE.stopAdvertise();
  
  // start advertising
  BLE.advertise();
}

it shows up again. I have to call BLE.advertise() after every disconnect to get it to show up again. Unplugging/replugging also fixes this issue.

Is this expected behavior?

[polldo]

Hi @sastorer-ms ,
I leave You the code I used to check this out.
Here all seems to be working, after calling BLE.disconnect() the device is advertising again and it handles new connections correctly.
I've used the ArduinoBLE library version 1.1.2-8-g3b228dc and the Arduino-nRF582x core version 1.1.5
You can use this sketch as a reference and post here your feedback. If You're still having problems, You could post here your sketch.
Thanks

#include <ArduinoBLE.h>

unsigned long connTime = 0;

void setup() {
    Serial.begin(115200);
    while (!Serial);

    if (!BLE.begin()) {
        Serial.println("starting BLE failed!");
        while (1);
    }

    BLE.debug(Serial);

    BLE.setLocalName("Test");
    BLE.setEventHandler(BLEConnected, blePeripheralConnectHandler);
    BLE.setEventHandler(BLEDisconnected, blePeripheralDisconnectHandler);
    BLE.advertise();
    Serial.println("BLE advertising as Test");
}

void blePeripheralConnectHandler(BLEDevice central) {
    Serial.println("Connected event, central: ");
    Serial.println(central.address());
    connTime = millis();
}

void blePeripheralDisconnectHandler(BLEDevice central) {
    Serial.println("Disconnected event, central: ");
    Serial.println(central.address());
}

void loop() {

    BLE.poll();

    if (BLE.connected()) {
        if (millis() > connTime + 10000) {
            Serial.println("time to disconnect");
            BLE.disconnect();
        }
    }
}