Working - using the emulator example

Author: PaulZC

examples/Example02_setFrequencyHz/Example02_setFrequencyHz.ino

@@ -37,7 +37,7 @@ void setup()
   myTCXO.setBaseFrequencyHz(10000000.0); // Pass the oscillator base frequency into the driver
 
   Serial.print("Base frequency set to ");
-  Serial.println(myTCXO.getBaseFrequencyHz());
+  Serial.print(myTCXO.getBaseFrequencyHz());
   Serial.println(" Hz");
 
   myTCXO.setPullRangeControl(SiT5358_PULL_RANGE_200ppm); // Set the pull range control to 200ppm
@@ -51,7 +51,7 @@ void setup()
   Serial.print(myTCXO.getFrequencyHz());
   Serial.println(" Hz");
 
-  Serial.print("Frequency control word should be 16777216. It is ");
+  Serial.print("Frequency control word should be 16777215. It is ");
   Serial.println(myTCXO.getFrequencyControlWord());
 }
 

examples/Example03_IllegalFrequency/Example03_IllegalFrequency.ino

@@ -0,0 +1,63 @@
+/*
+  Set the frequency of the SiT5358 DCTCXO.
+
+  This example demonstrates what happens when an illegal (out of bounds) frequency is selected.
+
+  By: Paul Clark
+  SparkFun Electronics
+  Date: 2024/8/1
+  SparkFun code, firmware, and software is released under the MIT License.
+  Please see LICENSE.md for further details.
+
+*/
+
+// You will need the SparkFun Toolkit. Click here to get it: http://librarymanager/All#SparkFun_Toolkit
+
+#include <SparkFun_SiT5358.h> // Click here to get the library: http://librarymanager/All#SparkFun_SiT5358
+
+SfeSiT5358ArdI2C myTCXO;
+
+void setup()
+{
+  delay(1000); // Allow time for the microcontroller to start up
+
+  Serial.begin(115200); // Begin the Serial console
+  while (!Serial)
+  {
+    delay(100); // Wait for the user to open the Serial Monitor
+  }
+  Serial.println("SparkFun SiT5358 Example");
+
+  Wire.begin(); // Begin the I2C bus
+
+  if (!myTCXO.begin())
+  {
+    Serial.println("SiT5358 not detected! Please check the address and try again...");
+    while (1); // Do nothing more
+  }
+
+  myTCXO.setBaseFrequencyHz(10000000.0); // Pass the oscillator base frequency into the driver
+
+  Serial.print("Base frequency set to ");
+  Serial.print(myTCXO.getBaseFrequencyHz());
+  Serial.println(" Hz");
+
+  myTCXO.setPullRangeControl(SiT5358_PULL_RANGE_200ppm); // Set the pull range control to 200ppm
+
+  Serial.print("Pull range control set to ");
+  Serial.println(myTCXO.getPullRangeControlText(myTCXO.getPullRangeControl()));
+
+  myTCXO.setFrequencyHz(9900000.0); // Try to set the frequency to 9.9MHz (-10000ppm)
+
+  Serial.print("Frequency set to ");
+  Serial.print(myTCXO.getFrequencyHz());
+  Serial.println(" Hz");
+
+  Serial.print("Frequency control word should be -33554432. It is ");
+  Serial.println(myTCXO.getFrequencyControlWord());
+}
+
+void loop()
+{
+  // Nothing to do here
+}

examples/Example04_setFrequencyByBiasMillis/Example04_setFrequencyByBiasMillis.ino

@@ -0,0 +1,97 @@
+/*
+  Set the frequency of the SiT5358 DCTCXO from RX clock delay.
+
+  This example demonstrates how to set the frequency of the SiT5358 DCTCXO from a GNSS
+  RX Clock Bias (in milliseconds).
+
+  By: Paul Clark
+  SparkFun Electronics
+  Date: 2024/8/1
+  SparkFun code, firmware, and software is released under the MIT License.
+  Please see LICENSE.md for further details.
+
+  Consider the SiT5358AI-FS033IT-10.000000 used on the SparkFun RTK mosaic-T:
+  The operating temperature range is Industrial, -40 to 85°C (option "I").
+  LVCMOS output (option "-").
+  Frequency stability +/-50ppb (option "S").
+  It is DCTCXO with an I2C address of 0x60 (option "0").
+  Supply voltage 3.3V (option "33").
+  Pin 1 is Output Enable (option "I"). (No software OE control).
+  The default pull range is 6.25ppm (option "T").
+  Base frequency is 10.000000MHz.
+
+  Consider this example:
+  * The TCXO frequency has not yet been changed. It is running at the default 10.000000 MHz.
+  * 10.000000 MHZ is the library default base frequency. But we could set it with setBaseFrequencyHz(10000000.0)
+  * The pull range is read during begin. But we could set it with setPullRangeControl(SiT5358_PULL_RANGE_6ppm25)
+  * The mosaic-T manual states that the oscillator frequency should be changed by no more than 3ppb per second.
+  * We tell the library this using setMaxFrequencyChangePPB(3.0)
+  * The GNSS RxClkBias reports that receiver time is ahead of system time by 200 nanoseconds (+200ns).
+  * We instruct the library to change the frequency using setFrequencyByBiasMillis(200.0e-6)
+  * The TCXO clock period is 100ns.
+  * The 200ns bias corresponds to 2 clock cycles.
+  * To remove that bias in one second, the oscillator frequency would need to be reduced to 9.999998 MHz.
+  * That is a change of 2 parts in 10000000, or 0.2ppm, or 200ppb.
+  * The frequency change will be limited to 3ppb.
+  * Since the SiT5358 Pull Range is set to 6.25ppm, and the Pull Register is 26-bit signed, 3ppb corresponds to 16106 LSB.
+  * The firmware writes the value -16106 to the Frequency Control Register, reducing the frequency to 9.99999997 MHz.
+  * getFrequencyHz will return 9999999.97
+
+*/
+
+// You will need the SparkFun Toolkit. Click here to get it: http://librarymanager/All#SparkFun_Toolkit
+
+#include <SparkFun_SiT5358.h> // Click here to get the library: http://librarymanager/All#SparkFun_SiT5358
+
+SfeSiT5358ArdI2C myTCXO;
+
+void setup()
+{
+  delay(1000); // Allow time for the microcontroller to start up
+
+  Serial.begin(115200); // Begin the Serial console
+  while (!Serial)
+  {
+    delay(100); // Wait for the user to open the Serial Monitor
+  }
+  Serial.println("SparkFun SiT5358 Example");
+
+  Wire.begin(); // Begin the I2C bus
+
+  if (!myTCXO.begin())
+  {
+    Serial.println("SiT5358 not detected! Please check the address and try again...");
+    while (1); // Do nothing more
+  }
+
+  myTCXO.setBaseFrequencyHz(10000000.0); // Pass the oscillator base frequency into the driver
+
+  Serial.print("Base frequency set to ");
+  Serial.print(myTCXO.getBaseFrequencyHz());
+  Serial.println(" Hz");
+
+  myTCXO.setPullRangeControl(SiT5358_PULL_RANGE_6ppm25); // Set the pull range control to 6.25ppm
+
+  Serial.print("Pull range control set to ");
+  Serial.println(myTCXO.getPullRangeControlText(myTCXO.getPullRangeControl()));
+
+  myTCXO.setMaxFrequencyChangePPB(3.0); // Set the maximum frequency change in PPB
+
+  Serial.print("Maximum frequency change set to ");
+  Serial.print(myTCXO.getMaxFrequencyChangePPB());
+  Serial.println(" PPB");
+
+  myTCXO.setFrequencyByBiasMillis(200.0e-6); // Set the frequency by clock bias (+200ns, +200e-6ms)
+
+  Serial.print("Frequency should be 9999999.97 Hz. It is ");
+  Serial.print(myTCXO.getFrequencyHz());
+  Serial.println(" Hz");
+
+  Serial.print("Frequency control word should be -16106. It is ");
+  Serial.println(myTCXO.getFrequencyControlWord());
+}
+
+void loop()
+{
+  // Nothing to do here
+}

examples/SiT5358_Emulator/SiT5358_Emulator.ino

@@ -0,0 +1,97 @@
+/*
+  Emulate the SiT5358 DCTCXO.
+
+  By: Paul Clark
+  SparkFun Electronics
+  Date: 2024/8/1
+  SparkFun code, firmware, and software is released under the MIT License.
+  Please see LICENSE.md for further details.
+
+*/
+
+#include <Wire.h>
+
+#define I2C_DEV_ADDR 0x60
+
+uint8_t registerBytes[6] = { 0, 0, 0, 0, 0, 0 };
+uint8_t registerAddress = 0;
+
+// On Request:
+// Write bytes from registerBytes, starting at registerAddress * 2
+void onRequest()
+{
+  int i = registerAddress * 2;
+  for (; i < 6; i++)
+    Wire.write(registerBytes[i]);
+}
+
+// On Receive:
+// Copy the first incoming byte into registerAddress
+// Copy the remaining bytes into registerBytes, starting at registerAddress * 2
+void onReceive(int len)
+{
+  int count = -1;
+  while (Wire.available())
+  {
+    uint8_t b = Wire.read();
+    switch (count)
+    {
+      case -1:
+        registerAddress = b;
+        break;
+      default:
+        if (((registerAddress * 2) + count) < 6)
+          registerBytes[((registerAddress * 2) + count)] = b;
+        break;
+    }
+    count++;
+  }
+}
+
+void setup()
+{
+  delay(1000); // Allow time for the microcontroller to start up
+
+  Serial.begin(115200); // Begin the Serial console
+  while (!Serial)
+  {
+    delay(100); // Wait for the user to open the Serial Monitor
+  }
+  Serial.println("SparkFun SiT5358 Emulator");
+
+  Wire.onReceive(onReceive);
+  Wire.onRequest(onRequest);
+  Wire.begin((uint8_t)I2C_DEV_ADDR);
+}
+
+void loop()
+{
+  static unsigned long lastPrint = 0;
+
+  if (millis() > (lastPrint + 1000))
+  {
+    lastPrint = millis();
+
+    // Extract the 26-bit Frequency Control Word
+    uint32_t freqControl = ((uint32_t)registerBytes[0]) << 8;
+    freqControl |= (uint32_t)registerBytes[1];
+    freqControl |= (((uint32_t)registerBytes[2]) & 0x03) << 24;
+    freqControl |= ((uint32_t)registerBytes[3]) << 16;
+    if (freqControl & 0x02000000) // Correct two's complement
+      freqControl |= 0xFC000000;
+    
+    union // Avoid any ambiguity when converting uint32_t to int32_t
+    {
+        uint32_t unsigned32;
+        int32_t signed32;
+    } unsignedSigned32;
+    unsignedSigned32.unsigned32 = freqControl;
+
+    Serial.print("Frequency control is ");
+    Serial.print(unsignedSigned32.signed32);
+
+    // Extract the 4-bit Pull Range Control
+    Serial.print(". Pull range control is ");
+    Serial.println(registerBytes[5]);
+  }
+}

src/SparkFun_SiT5358.cpp

@@ -261,7 +261,29 @@ void SfeSiT5358Driver::setMaxFrequencyChangePPB(double ppb)
 ///       and the setMaxFrequencyChangePPB. Call getFrequencyHz to read the frequency set.
 bool SfeSiT5358Driver::setFrequencyByBiasMillis(double bias)
 {
-    return false;
+    double freq = getFrequencyHz();
+
+    double clockInterval_s = 1.0 / freq; // Convert freq to interval in seconds
+
+    double biasInClocks = bias / 1000.0; // Convert bias from millis to seconds
+    biasInClocks /= clockInterval_s; // Convert bias to clock cycles
+
+    double maxChangeInClocks = freq * _maxFrequencyChangePPB / 1.0e9;
+
+    if (biasInClocks >= 0.0)
+    {
+        if (biasInClocks > maxChangeInClocks)
+            biasInClocks = maxChangeInClocks;
+    }
+    else
+    {
+        if (biasInClocks < (0.0 - maxChangeInClocks))
+            biasInClocks = 0.0 - maxChangeInClocks;
+    }
+
+    double newFreq = freq - biasInClocks;
+
+    return setFrequencyHz(newFreq);
 }
 
 /// @brief Convert the 4-bit pull range into text

src/SparkFun_SiT5358.h

@@ -25,33 +25,6 @@
     To set the oscillator to a specific frequency, it is necessary to know the base frequency
     and pull range limit (in ppm). The frequency control word defines the pull as fractional ppm.
 
-    Consider the SiT5358AI-FS033IT-10.000000 used on the SparkFun RTK mosaic-T:
-    The operating temperature range is Industrial, -40 to 85°C (option "I").
-    LVCMOS output (option "-").
-    Frequency stability +/-50ppb (option "S").
-    It is DCTCXO with an I2C address of 0x60 (option "0").
-    Supply voltage 3.3V (option "33").
-    Pin 1 is Output Enable (option "I"). (No software OE control).
-    The default pull range is 6.25ppm (option "T").
-    Base frequency is 10.000000MHz.
-
-    Consider this example:
-    * The TCXO frequency has not yet been changed. It is running at the default 10.000000 MHz.
-    * 10.000000 MHZ is the library default base frequency. But we could set it with setBaseFrequencyHz(10000000.0)
-    * The pull range is read during begin. But we could set it with setPullRangeControl(SiT5358_PULL_RANGE_6ppm25)
-    * The mosaic-T manual states that the oscillator frequency should be changed by no more than 3ppb per second.
-    * We tell the library this using setMaxFrequencyChangePPB(3.0)
-    * The GNSS RxClkBias reports that receiver time is ahead of system time by 200 nanoseconds (+200ns).
-    * We instruct the library to change the frequency using setFrequencyByBiasMillis(200.0e-6)
-    * The TCXO clock period is 100ns.
-    * The 200ns bias corresponds to 2 clock cycles.
-    * To remove that bias in one second, the oscillator frequency would need to be reduced to 9.999998 MHz.
-    * That is a change of 2 parts in 10000000, or 0.2ppm, or 200ppb.
-    * The frequency change will be limited to 3ppb.
-    * Since the SiT5358 Pull Range is set to 6.25ppm, and the Pull Register is 26-bit signed, 3ppb corresponds to 16106 LSB.
-    * The firmware writes the value -16106 to the Frequency Control Register, reducing the frequency to 9.99999997 MHz.
-    * getFrequencyHz will return 9999999.97
-
 */
 
 #pragma once